/*
   Greenhouse macro. 
        6/29/1001  Oliver Knill, Harvard University

   Given 8 Points P1,P2, ... P8, build a 
   glasshouse open one one side

       +--------------------------------------+
      / P8                                   /| P7
  nz /                                      / |
    /                                      /  |
P4 +--------------------------------------+ P3|
   |                                      |   |
   |   P5          D---- C                |   + P6
ny +               |     |                +  / 
   |               A-----B                | / 
   |                                      |/ 
P1 +--------------------------------------+  P2
                    nx

*/

#declare glass_1001 =
texture {
    pigment { color rgbf<1.0, 1.0, 1.0, 0.7> }
    finish { specular 1 roughness 0.001 ambient 0 diffuse 0 reflection 0.1 }
}

#declare white_wood =
texture {
    pigment { color rgb<1.0, 1.0, 1.0> }
    finish { specular 1 ambient 0 diffuse 0.3 reflection 0.7 }
}

#macro window(P1,P2,P3,P4,nx,ny,r)
  union {
  #local i=0;
  #while (i<nx)
  #local j=0;
  #while (j<ny)
      #local A=P1+i*(P2-P1)/nx+j*(P4-P1)/ny;
      #local B=P1+(i+1)*(P2-P1)/nx+j*(P4-P1)/ny;
      #local C=P1+(i+1)*(P2-P1)/nx+(j+1)*(P4-P1)/ny;
      #local D=P1+i*(P2-P1)/nx+(j+1)*(P4-P1)/ny;
      object{
         polygon {5,A,B,C,D,A}
         texture {glass_1001}
      }
  #local j=j+1;
  #end
  #local i=i+1;
  #end

  #local j=0;
  #while (j<=ny)
      #local A=P1+j*(P4-P1)/ny;
      #local B=P2+j*(P4-P1)/ny;
      object {
         cylinder {A,B, r }
         texture {white_wood }
      }
      #local j=j+1;
  #end

  #local i=0;
  #while (i<=nx)
      #local A=P1+i*(P2-P1)/nx;
      #local B=P4+i*(P2-P1)/nx;
      object {
         cylinder {A,B, r }
         texture {white_wood }
      }
      #local i=i+1;
  #end
 }
#end

#macro window1(P1,P2,P3,P4,nx,ny,r,NN,dd)
  #local i=0;
  #while (i<nx)
  #local j=0;
  #while (j<ny)
      #local A=P1+i*(P2-P1)/nx+j*(P4-P1)/ny;
      #local B=P1+(i+1)*(P2-P1)/nx+j*(P4-P1)/ny;
      #local C=P1+(i+1)*(P2-P1)/nx+(j+1)*(P4-P1)/ny;
      #local D=P1+i*(P2-P1)/nx+(j+1)*(P4-P1)/ny;
      object{
         polygon {5,A,B,C,D,A}
         clipped_by {plane {NN, dd } } 
         texture {glass_1001}
      }
  #local j=j+1;
  #end
  #local i=i+1;
  #end

  #local j=0;
  #while (j<=ny)
      #local A=P1+j*(P4-P1)/ny;
      #local B=P2+j*(P4-P1)/ny;
      object {
         cylinder {A,B, r }
         clipped_by {plane {NN, dd } } 
         texture {white_wood }
      }
      #local j=j+1;
  #end

  #local i=0;
  #while (i<=nx)
      #local A=P1+i*(P2-P1)/nx;
      #local B=P4+i*(P2-P1)/nx;
      object {
         cylinder {A,B, r }
         clipped_by {plane {NN, dd } } 
         texture {white_wood }
      }
      #local i=i+1;
  #end
#end


#macro green_house(PP1,PP2,PP3,PP4,PP5,PP6,PP7,PP8,nx,ny,nz,r)
  // build front windows
  window(PP1,PP2,PP3,PP4,nx,ny,r)
  window(PP4,PP3,PP7,PP8,nx,nz,r)
  #local PP8=PP6+(PP3-PP2); 
  #local PP10=PP2+(PP7-PP6); 
  #local PP11=PP6+(PP3-PP2); 
  #local PP12=PP2+(PP7-PP6); 
  #local NN=<0,-(PP3-PP7).z,(PP3-PP7).y>;              // normal to roof
  #local dd=vdot(NN,PP3)/sqrt(vdot(NN,NN));            // distance of roof to origin
  window(PP2,PP6,PP8,PP3,nz,ny,r)
  window1(PP3,PP8,PP7,PP10,nz,ny,r,NN,dd) 
  union {
    sphere{ PP1, r } sphere{ PP2, r } sphere{ PP3, r } sphere{ PP4, r }
    sphere{ PP5, r } sphere{ PP6, r } sphere{ PP8, r } sphere{ PP7, r }
    texture { white_wood } 
   } 
#end